DEFINE PERSONA.ANHOSEST_B
    AS SWITCH
    INCASE PERSONA.P37A < 4
    ASSIGN 0
    INCASE PERSONA.P37A = 4 OR PERSONA.P37A = 7 OR PERSONA.P37A = 9
    ASSIGN PERSONA.P37B
    INCASE PERSONA.P37A = 5
    ASSIGN PERSONA.P37B + 5
    INCASE PERSONA.P37A = 6 OR PERSONA.P37A = 8
    ASSIGN PERSONA.P37B + 8
    INCASE PERSONA.P37A = 10
    ASSIGN PERSONA.P37B + 6
    INCASE PERSONA.P37A = 11 OR PERSONA.P37A = 12
    ASSIGN PERSONA.P37B + 12
    INCASE PERSONA.P37A = 13
   /* * Asume que para hacer una maestría (P37A = 13) debe haber cumplido la licenciatura
    * (cinco años) y el/los ciclos anteriores que siempre suman 12 años en total    */
    ASSIGN PERSONA.P37B + 17
    INCASE PERSONA.P37A = 14
  /*  * Asume que para hacer un Doctorado (P37A = 14) debe haber cursado
    * dos años de maestría   */
    ASSIGN PERSONA.P37B + 19
             /*
    ************************************************************************
    ********************* Para nivel No Universitario***********************
    ************************************************************************

    *A) Personas que terminaron la educación media o secundaria en cualquiera
    *   de los tres sistemas (antiguo, anterior o actual)      */
    INCASE PERSONA.P37A >= 15 AND PERSONA.P37A <= 17 AND PERSONA.P37B >= 1 AND 
           (PERSONA.P38A = 3 OR PERSONA.P38A = 5) AND PERSONA.P38B = 4
    ASSIGN (PERSONA.P38B + 8) + PERSONA.P37B
    
    INCASE PERSONA.P37A >= 15 AND PERSONA.P37A <= 17 AND PERSONA.P37B >= 1 AND 
           (PERSONA.P38A = 7) AND PERSONA.P38B = 6
    ASSIGN (PERSONA.P38B + 6) + PERSONA.P37B
      /*
    *B) Personas que NO terminaron la educación media o secundaria en 
    *   cualquiera de los tres sistemas (antiguo, anterior o actual),
    *   pero informan haber cursado estudios no universitarios; se trata
    *   de casos inconsistentes... SE LES ASIGNA LOS AÑOS DE ESTUDIO PARA
    *   NIVELES NO SUPERIORES (desde basico/primario hasta medio/secundario)  */
    INCASE PERSONA.P37A >= 15 AND PERSONA.P37A <= 17 AND PERSONA.P37B >= 1 AND 
           ((PERSONA.P38B < 6 AND PERSONA.P38B <> 4) OR PERSONA.P38B =8) AND
           PERSONA.P38A = 2
    ASSIGN (PERSONA.P38B + 5)
    INCASE PERSONA.P37A >= 15 AND PERSONA.P37A <= 17 AND PERSONA.P37B >= 1 AND 
           ((PERSONA.P38B < 6 AND PERSONA.P38B <> 4) OR PERSONA.P38B =8) AND
           (PERSONA.P38A = 3  OR PERSONA.P38A = 5)
    ASSIGN (PERSONA.P38B + 8) 
    INCASE PERSONA.P37A >= 15 AND PERSONA.P37A <= 17 AND PERSONA.P37B >= 1 AND 
           ((PERSONA.P38B < 6 AND PERSONA.P38B <> 4) OR PERSONA.P38B =8) AND
           (PERSONA.P38A = 1 OR PERSONA.P38A = 4 OR PERSONA.P38A = 6)
    ASSIGN PERSONA.P38B
    INCASE PERSONA.P37A >= 15 AND PERSONA.P37A <= 17 AND PERSONA.P37B >= 1 AND 
           ((PERSONA.P38B < 6 AND PERSONA.P38B <> 4) OR PERSONA.P38B =8) AND
           PERSONA.P38A = 7
    ASSIGN (PERSONA.P38B + 6)
    INCASE PERSONA.P37A = 18 AND PERSONA.P37B = 0 AND 
           (PERSONA.P38A = 1 OR PERSONA.P38A = 4 OR PERSONA.P38A = 6)
    ASSIGN PERSONA.P38B
    INCASE PERSONA.P37A = 18 AND PERSONA.P37B = 0 AND PERSONA.P38A = 2
    ASSIGN PERSONA.P38B + 5
    INCASE PERSONA.P37A = 18 AND PERSONA.P37B = 0 AND 
           (PERSONA.P38A = 3 OR PERSONA.P38A = 5)
    ASSIGN PERSONA.P38B + 8
    INCASE PERSONA.P37A = 18 AND PERSONA.P37B = 0 AND PERSONA.P38A = 7
    ASSIGN PERSONA.P38B + 6
    ELSE 99
    TYPE INTEGER
    RANGE 0 - 99
    VALUELABELS 99 "Omitidos"
    MISSING 99
    varlabel "Años de estudio"

DEFINE PERSONA.EDADQUIN
	AS RECODE PERSONA.P25
	(0 : 4 = 1)
	(5 : 9 = 2)
	(10 : 14 = 3)
	(15 : 19 = 4)
	(20 : 24 = 5)
	(25 : 29 = 6)
	(30 : 34 = 7)
	(35 : 39 = 8)
	(40 : 44 = 9)
	(45 : 49 = 10)
	(50 : 54 = 11)
	(55 : 59 = 12)
	(60 : 64 = 13)
	(65 : 69 = 14)
	(70 : 74 = 15)
	(75 : 79 = 16)
	(80 : 84 = 17)
	(85 : 89 = 18)
	(90 : 94 = 19)
	(95 : 99 = 20)
	(100 : 104 = 21)
	(105 : 109 = 22)
	(110 : 114 = 23)
	ELSE 25
	TYPE INTEGER
	RANGE (1 : 23) 
	VARLABEL "Grupos de edad quinquenal"
	VALUELABELS
		1 "	 0  - 4	"
		2 "	 5  - 9	"
		3 "	 10  - 14	"
		4 "	 15  - 19	"
		5 "	 20  - 24	"
		6 "	 25  - 29	"
		7 "	 30  - 34	"
		8 "	 35  - 39	"
		9 "	 40  - 44	"
		10 "	 45  - 49	"
		11 "	 50  - 54	"
		12 "	 55  - 59	"
		13 "	 60  - 64	"
		14 "	 65  - 69	"
		15 "	 70  - 74	"
		16 "	 75  - 79	"
		17 "	 80  - 84	"
		18 "	 85  - 89	"
		19 "	 90  - 94	"
		20 "	 95  - 99	"
		21 "	 100  - 104	"
		22 "	 105  - 109	"
		23 "	 110  - 114	"
	MISSING 26
	NOTAPPLICABLE 27

DEFINE PERSONA.CONDICIUD
AS SWITCH
INCASE PERSONA.CIUDADHABI     <>  PERSONA.CIUD5ANOS  ASSIGN 0
INCASE PERSONA.CIUDADHABI   = PERSONA.CIUD5ANOS  ASSIGN 1
RANGE 0 - 1
VARLABEL "Condicion de migrante reciente en ciudades"
VALUELABELS
0 "Migrante"
1 "No migrante"

TABLE EE 
AS FREQUENCY
	OF PERSONA.EDADQUIN
	BY PERSONA.ANHOSEST_B
	BY PERSONA.CONDICIUD
    FILTER PERSONA.P25 > 4 AND PERSONA.P34A > 0 AND PERSONA.P34A < 3 
    AND PERSONA.P33A > 0 AND PERSONA.P33A < 3 and  PERSONA.ANHOSEST_B < 99